Private Sub City_NotInList(NewData As String, Response As Integer)
Rem ----------------------------------------------------------------------
Rem Esempio commentato di routine Non In Elenco
Rem Le righe con Rem sono i commenti
Rem Inserire la routine nell'evento non in elenco e modificarla a piacere
Rem ----------------------------------------------------------------------
Rem In queste righe si dichiarano le variabili che saranno utilizzate
Dim City As String
Dim Risposta As Integer, varName As Variant
    City = NewData

Rem ----------------------------------------------------------------------
Rem Si genera il messaggio di richiesta di inserimento
Rem Se la risposta è Si si apre la maschera venditori (o altra) in
Rem modalità aggiornamento (DataMode:=acAdd)
Rem ----------------------------------------------------------------------
    Risposta = MsgBox("Città " & City & _
        " non nel sistema.  Si desidera aggiungerla?", _
        vbQuestion + vbYesNo, "ISI")
    If Risposta = vbYes Then
        DoCmd.OpenForm FormName:="City", _
            DataMode:=acAdd, WindowMode:=acDialog, OpenArgs:=City

Rem ----------------------------------------------------------------------
Rem La funzione DLookup cerca nella tabella i dati appena inseriti per
Rem renderli disponibili alla maschera in cui saranno usati. Se così non fosse
Rem per vedere l'inserimento si dovrebbe uscire dalla maschera e rientrare
Rem Per usare DLookup si devono inserire i dati così:
Rem DLookup("Campo Chiave Tabella", "Nome Tabella", "[Campo da confrontare] = """ & Variabile inserita & """")
Rem Questo esempio è semplice perchè tutte le voci si chiamano City
Rem ----------------------------------------------------------------------

        If IsNull(DLookup("City", "City", "[City] = """ & City & """")) Then
            Response = acDataErrContinue
            Else
            Response = acDataErrAdded
        End If
        Exit Sub
    End If
End Sub